Press "Enter" to skip to content

Сброс центра обновления Windows 10

При возникновении ошибок при загрузке или установке обновлений чаще всего помогает центра обновления Windows 10. В данной статье мы опишем стандартные методы, как сбросить Центр обновления и решить проблемы с обновлениями.

 

Существует несколько известных способов сбросить Центр обновления Windows 10:

  • Используя средство устранения неполадок
  • Удаление папки SoftwareDistibution
  • Выполнение скрипта

Разберем данные способы по порядку.

Средство устранения неполадок

Помогает в 2 случаях из 10 и может указывать на ошибки хранилища компонентов и самого ЦО, без наличия таковых. Не самое лучше средство решение проблемы, но иногда помогает. Редко, но помогает. Учитывая заявление Microsoft, что все траблшутеры (а именно так называются эти средства устранения неполадок) совершенствуются и «учатся на ошибках», этого не было замечено за всё время использования системы.

Средство устранения неполадок Центра обновления Windows

Если Вам требуется запустить средство устранения неполадок Центра обновления Windows, пройдите в Панель управления — Устранение неполадок — Все категории и запустите нужное средство от имени Администратора.

 

Удаление папки SoftwareDistibution

Решает 5 из 10 проблем с обновлениями. SoftwareDistibution – папка, где хранятся загруженные обновления, кэш Центра обновления и его логи. Удаление данной папки решает вопросы ошибок установки, но не загрузки обновлений.

Папка располагается по пути C:\Windows\SoftwareDistribution

Перед тем, как её удалить, необходимо остановить службу Центр обновления Windows или выполнить следующую команду в Командной строке от имени Администратора:

net stop wuauserv

 

остановка службы Центра обновления Windows

Выполнение скрипта

Универсальное средство для решения проблем обновлений, как для Windows 10, так и для Windows 8.1 и 7. Решает 8 из 10 проблем связанных с центром обновления. Есть 2 варианта использования скрипта:

  1. Загрузить скрипт с форума Microsoft

Пройдите на страницу загрузки Technet Microsoft или загрузите архив по прямой ссылке. Распакуйте архив и запустите скрипт ResetWUEng от имени Администратора.

Первая страница предостерегает о возможных последствиях (скрипт умеет не только сбрасывать ЦО), для согласия нажмите клавишу «. На выбор будет предложено 17 действий, но нам нужно только одно, под цифрой 2. Нажимаем 2 и клавишу Enter. На экране будут отображаться выполняемые процессы и по завершению возникнет окно в 17 вариантами. Выберите 17 для перезагрузки и нажмите Enter.

 как сбросить Центр обновления Windows скриптом

Примечание: Некоторые антивирусы могут «ругаться» на данный скрипт, но открыв Блокнотом, Вы можете удостовериться, что ничего подозрительного в его содержимом нету.

  1. Создание скрипта самостоятельно

Сделать скрипт для сброса Центра обновления Windows довольно просто, нам потребуется для начала открыть Блокнот (notepad.exe) и скопировать туда данный текст:

 

@echo off

::Сброс центра обновлений
::WindowsGuide.ru

:: Checking and Stopping the Windows Update services
set b=0

:bits
set /a b=%b%+1
if %b% equ 3 (
   goto end1
)

net stop bits
echo Checking the bits service status.
sc query bits | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto bits
)
goto loop2

:end1
cls
echo.
echo Cannot reset Windows Update since "Background Intelligent Transfer Service" (bits) service failed to stop.
echo.
pause
goto Start

:loop2
set w=0

:wuauserv
set /a w=%w%+1
if %w% equ 3 (
   goto end2
)
net stop wuauserv
echo Checking the wuauserv service status.
sc query wuauserv | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto wuauserv
)
goto loop3

:end2
cls
echo.
echo Cannot reset Windows Update since "Windows Update" (wuauserv) service failed to stop.
echo.
pause
goto Start

:loop3
set app=0
:appidsvc
set /a app=%app%+1
if %app% equ 3 (
   goto end3
)
net stop appidsvc
echo Checking the appidsvc service status.
sc query appidsvc | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto appidsvc
)
goto loop4

:end3
cls
echo.
echo Cannot reset Windows Update since "Application Identity" (appidsvc) service failed to stop.
echo.
pause
goto Start

:loop4
set c=0

:cryptsvc
set /a c=%c%+1
if %c% equ 3 (
   goto end4
)
net stop cryptsvc
echo Checking the cryptsvc service status.
sc query cryptsvc | findstr /I /C:"STOPPED"
if not %errorlevel%==0 (
    goto cryptsvc
)
goto Reset

:end4
cls
echo.
echo Cannot reset Windows Update since "Cryptographic Services" (cryptsvc) service failed to stop.
echo.
pause
goto Start

:Reset
Ipconfig /flushdns
del /s /q /f "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\qmgr*.dat"
del /s /q /f "%ALLUSERSPROFILE%\Microsoft\Network\Downloader\qmgr*.dat"
del /s /q /f "%SYSTEMROOT%\Logs\WindowsUpdate\*"

if exist "%SYSTEMROOT%\winsxs\pending.xml.bak" del /s /q /f "%SYSTEMROOT%\winsxs\pending.xml.bak"
if exist "%SYSTEMROOT%\winsxs\pending.xml" (
    takeown /f "%SYSTEMROOT%\winsxs\pending.xml"
    attrib -r -s -h /s /d "%SYSTEMROOT%\winsxs\pending.xml"
    ren "%SYSTEMROOT%\winsxs\pending.xml" pending.xml.bak
)

if exist "%SYSTEMROOT%\SoftwareDistribution.bak" rmdir /s /q "%SYSTEMROOT%\SoftwareDistribution.bak"
if exist "%SYSTEMROOT%\SoftwareDistribution" (
    attrib -r -s -h /s /d "%SYSTEMROOT%\SoftwareDistribution"
    ren "%SYSTEMROOT%\SoftwareDistribution" SoftwareDistribution.bak
)

if exist "%SYSTEMROOT%\system32\Catroot2.bak" rmdir /s /q "%SYSTEMROOT%\system32\Catroot2.bak"
if exist "%SYSTEMROOT%\system32\Catroot2" (
    attrib -r -s -h /s /d "%SYSTEMROOT%\system32\Catroot2"
    ren "%SYSTEMROOT%\system32\Catroot2" Catroot2.bak
)

:: Reset Windows Update policies
reg delete "HKCU\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate" /f
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\WindowsUpdate" /f
gpupdate /force

:: Reset the BITS service and the Windows Update service to the default security descriptor
sc.exe sdset bits D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)

sc.exe sdset wuauserv D:(A;;CCLCSWRPWPDTLOCRRC;;;SY)(A;;CCDCLCSWRPWPDTLOCRSDRCWDWO;;;BA)(A;;CCLCSWLOCRRC;;;AU)(A;;CCLCSWRPWPDTLOCRRC;;;PU)

:: Reregister the BITS files and the Windows Update files
cd /d %windir%\system32
regsvr32.exe /s atl.dll
regsvr32.exe /s urlmon.dll
regsvr32.exe /s mshtml.dll
regsvr32.exe /s shdocvw.dll
regsvr32.exe /s browseui.dll
regsvr32.exe /s jscript.dll
regsvr32.exe /s vbscript.dll
regsvr32.exe /s scrrun.dll
regsvr32.exe /s msxml.dll
regsvr32.exe /s msxml3.dll
regsvr32.exe /s msxml6.dll
regsvr32.exe /s actxprxy.dll
regsvr32.exe /s softpub.dll
regsvr32.exe /s wintrust.dll
regsvr32.exe /s dssenh.dll
regsvr32.exe /s rsaenh.dll
regsvr32.exe /s gpkcsp.dll
regsvr32.exe /s sccbase.dll
regsvr32.exe /s slbcsp.dll
regsvr32.exe /s cryptdlg.dll
regsvr32.exe /s oleaut32.dll
regsvr32.exe /s ole32.dll
regsvr32.exe /s shell32.dll
regsvr32.exe /s initpki.dll
regsvr32.exe /s wuapi.dll
regsvr32.exe /s wuaueng.dll
regsvr32.exe /s wuaueng1.dll
regsvr32.exe /s wucltui.dll
regsvr32.exe /s wups.dll
regsvr32.exe /s wups2.dll
regsvr32.exe /s wuweb.dll
regsvr32.exe /s qmgr.dll
regsvr32.exe /s qmgrprxy.dll
regsvr32.exe /s wucltux.dll
regsvr32.exe /s muweb.dll
regsvr32.exe /s wuwebv.dll
regsvr32.exe /s wudriver.dll
netsh winsock reset
netsh winsock reset proxy
:: Set the startup type as automatic
sc config wuauserv start= auto
sc config bits start= auto
sc config DcomLaunch start= auto


:Start
net start bits
net start wuauserv
net start appidsvc
net start cryptsvc

Затем, сохраните данный файл и при сохранении укажите Тип файла: Все файлы, а в названии укажите назание.bat (например, wu.bat), что бы этот файл был исполняемым и можно было воспроизвести скрипт.

После сохранения откройте файл от имени Администратора и дождитесь окончания процедуры, после чего перезагрузите компьютер.

Мы надеемся, что данная инструкция была Вам полезна и помогла решить вопрос Центра обновления Windows.

Будет интересно: Ошибка Windows 10: 0x80072f8f

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *

Adblock detector